经典旧世法师宏与其他一些建议

受朋友委托，设计了整套怀旧服法师宏与按键体系。
在这里发表出来，送给有需要的人。
对自己当前宏与按键不太满意的朋友，可以尝试下，初次使用或许不习惯。
但是你用这套宏与按键打一个小时野怪以作适应练习之后，可能会有惊喜。


一、按键设置
W、S、A、D四键移动，鼠标右键转向。
[按键设置]里的默认组合键建议全部解除以避免跟宏冲突，修饰键在宏内体现作用。
修饰键主要使用ALT，如果你更习惯CTRL或SHIFT，交换即可。
主要技能栏均设置顺手快捷键，一共18个，涵盖所有战斗技能。
次要技能栏除坐骑外均无快捷键，一共10个，放置非战斗技能。

主要技能栏设置：
动作条一9、0、-、=依次设为：Q、E、R、F；
左下动作条1、2、3、4依次设为：F1、F2、F3、F4；
左下动作条7、8、9、10、11、12依次设为：Z、X、鼠标中键、滚轮前滚、滚轮后滚、鼠标键4。


次要技能栏设置：



二、宏设置
所有宏图标强烈建议使用红色问号图标。
未开启插件自动站立的玩家，可以酌情加入/stand语句。
未开启插件自动下马的玩家，可以酌情加入/dismount语句。
建议勾选[界面设置→战斗→自动自我施法]，可节省宏内自我指向条件语句。
本套宏适用于多种天赋。

[动作条一]
按键1：
#showtooltip [mod:alt] 射击;冰霜新星
/cancelaura 寒冰屏障
/equipslot [mod:alt] 16 搜魂者
/cast [mod:alt] 射击;冰霜新星
说明：1——施放冰霜新星；ALT+1——施放魔杖射击、装备常规武器。
/cancelaura 寒冰屏障——移除寒冰屏障。

按键2：
#showtooltip [mod:alt] 奥术飞弹;法术反制
/cancelaura 寒冰屏障
/stopcasting [nomod:alt]
/cast [mod:alt,nochanneling] 奥术飞弹;[nomod:alt,@mouseover,harm,nodead][nomod:alt] 法术反制
说明：2——鼠标划过目标敌对且未死亡则对其施放法术反制，否则对目标施放法术反制；
ALT+2——施放奥术飞弹。
/stopcasting——打断当前施法，保证及时施放法术反制。
nochanneling——不处于通道法术引导状态，防止重复按键打断正在施放的奥弹。

按键3：
#showtooltip [mod:alt] 制造魔法玛瑙;暴风雪
/cancelaura 寒冰屏障
/cast [mod:alt] 暴风雪(等级 1);暴风雪
说明：3——施放暴风雪；ALT+3——施放1级暴风雪。
按下ALT后本宏不会显示暴风雪图标代之以制造魔法玛瑙，以便和顶级暴风雪作区别。

按键4：
#showtooltip
/cancelaura 寒冰屏障
/cast [mod:alt] 火球术;烈焰风暴
说明：4——施放烈焰风暴；ALT+4——施放火球术。

按键Q：
#showtooltip [mod:shift] 魔法抑制;[mod:alt] 制造魔法玛瑙;寒冰箭
/use [nomod,harm,nodead] 短暂能量护符
/use [nomod,harm,nodead] 思维加速宝石
/cancelaura 寒冰屏障
/use [mod:shift] 魔法抑制;[mod:alt] 寒冰箭(等级 1);寒冰箭
/use [equipped:鱼竿] 钓鱼
说明：Q——使用饰品、施放寒冰箭或钓鱼；SHIFT+Q——施放魔法抑制；
ALT+Q——施放1级寒冰箭；CTRL+Q——施放寒冰箭。
按下ALT后本宏不会显示寒冰箭图标代之以制造魔法玛瑙，以便和顶级寒冰箭作区别。
奥冰天赋，本宏可以替换为如下宏：
#showtooltip [mod:shift] 魔法抑制;[mod:alt] 制造魔法玛瑙;寒冰箭
/use [nomod,harm,nodead] 奥术强化
/use [nomod,harm,nodead] 短暂能量护符
/use [nomod,harm,nodead] 思维加速宝石
/use [nomod,harm,nodead] 气定神闲
/use [mod:shift] 魔法抑制;[mod:alt] 寒冰箭(等级 1);寒冰箭
说明：Q——施放奥强、饰品、气定、寒冰箭；SHIFT+Q——施放魔法抑制；
ALT+Q——施放1级寒冰箭；CTRL+Q——施放寒冰箭。
火焰天赋，本宏可以替换为如下宏：
#showtooltip [mod:shift] 魔法抑制;[mod:alt] 炎爆术;火球术
/use [nomod,harm,nodead] 燃烧
/use [nomod,harm,nodead] 短暂能量护符
/use [nomod,harm,nodead] 思维加速宝石
/use [mod:shift] 魔法抑制;[mod:alt] 炎爆术;火球术
/use [equipped:鱼竿] 钓鱼
说明：Q——使用饰品、施放火球术或钓鱼；SHIFT+Q——施放魔法抑制；
ALT+Q——施放炎爆术；CTRL+Q——施放火球术。

按键E：
#showtooltip
/cancelaura 寒冰屏障
/cast [mod:shift] 魔法增效;[mod:alt] 缓落术;[mod:ctrl,@mouseover,harm,nodead][mod:ctrl] 变形术;火焰冲击
/cast [nomod] 射击
说明：E——施放火焰冲击，不能施放火焰冲击则施放魔杖射击；SHIFT+E——施放魔法增效；
ALT+E——施放缓落术；CTRL+E——鼠标划过目标敌对且未死亡则对其施放变形术，否则对目标施放变形术。
harm/help等判定条件在不指明判定对象的情况下默认对象为target；
对象拥有harm/help等属性的前提条件是必须存在，故harm/help包含exists；
所以
[harm]==[target=target,exists,harm]
[help]==[target=target,exists,help]

按键R：
#showtooltip [mod:alt] 制造魔法玛瑙;冰锥术
/cancelaura 寒冰屏障
/cast [mod:alt] 冰锥术(等级 1);冰锥术
说明：R——施放冰锥术；ALT+R——施放1级冰锥术。
按下ALT后本宏不会显示冰锥术图标代之以制造魔法玛瑙，以便和顶级冰锥术作区别。

按键F：
#showtooltip [mod:alt] 唤醒;闪现术
/cancelaura 寒冰屏障
/stopcasting [nomod:alt]
/equipslot [mod:alt] 16 娅尔罗的意志
/cast [mod:alt] 唤醒;闪现术
说明：F——施放闪现术；ALT+F——装备唤醒杖、施放唤醒。


[左下动作条]
按键F1：
#showtooltip
/cancelaura 寒冰屏障
/stopcasting
/cast 寒冰护体
说明：F1——施放寒冰护体。
火焰天赋，本宏可以替换为顶级寒冰箭。

按键F2：
#showtooltip
/use [combat][button:2] 急速冷却;魔法晶水
说明：F2——战斗状态或右键施放急速冷却，非战斗状态使用魔法晶水。
火焰天赋，本宏可以替换为如下宏：
#showtooltip
/use [combat][button:2] 寒冰箭(等级 1);魔法晶水
说明：说明：F2——战斗状态或右键施放一级寒冰箭，非战斗状态使用魔法晶水。

按键F3：
#showtooltip
/use [combat][button:2] 法力护盾;魔法甜面包
/use [nocombat,nobutton:2] 魔法晶水
说明：F3——战斗状态或右键施放法力护盾，非战斗状态使用面包和水。

按键F4：
无宏，绷带。

按键Z：
#showtooltip
/use [mod:ctrl/shift] 铁皮手雷;灼烧
说明：Z——施放灼烧；CTRL/SHIFT+Z——使用铁皮手雷。

按键X：
#showtooltip
/use [mod:ctrl/shift] 铁皮手雷;@mouseover,help,nodead[] 解除次级诅咒
说明：X——鼠标划过目标友善且未死亡则对其施放解除次级诅咒，否则对目标施放解除次级诅咒；
CTRL/SHIFT+X——使用铁皮手雷。
@mouseover,help,nodead[]——
第一个条件@mouseover,help,nodead检测鼠标划过目标，如果存在且友善且活着，则对其施放技能；
第一个条件不成立的情况下才会检测第二个条件；
第二个条件[]是一个无内容的空条件，空条件视为恒成立的条件，技能施放对象默认为目标。

鼠标中键：
#showtooltip
/stopcasting [nomod:ctrl]
/castsequence [mod:shift] 地精工兵炸药;[mod:alt] 有限无敌药水;[mod:ctrl] 逃命专家;reset=299 !寒冰屏障,急速冷却
说明：鼠标中键——依次施放寒冰屏障、急速冷却；SHIFT+中键——使用地精工兵炸药；
ALT+中键——使用有限无敌药水；CTRL+中键——施放逃命专家。
!寒冰屏障——某些技能有激活和取消两种状态，叹号会屏蔽取消功能，此处防止狂按键取消冰箱。
火焰天赋，本宏可以替换为如下宏：
#showtooltip
/stopcasting [nomod:ctrl]
/use [mod:shift] 地精工兵炸药;[mod:alt] 有限无敌药水;[mod:ctrl] 逃命专家;冲击波
/use [mod:shift] 冲击波
说明：鼠标中键——施放冲击波；SHIFT+中键——使用地精工兵炸药、冲击波；
ALT+中键——使用有限无敌药水；CTRL+中键——施放逃命专家。

滚轮前滚：
#showtooltip [mod:shift] 法力红宝石;[mod:alt] 特效法力药水;[mod:ctrl] 制造魔法玛瑙;魔爆术
/stopcasting
/use [mod:shift] 法力红宝石;[mod:alt] 特效法力药水;[mod:ctrl] 魔爆术(等级 1);魔爆术
/use [mod:shift] 法力黄水晶
/use [mod:shift] 大法师之袍
说明：滚轮前滚——施放魔爆术；SHIFT+前滚——使用各种法力宝石、大法师之袍；
ALT+前滚——使用大蓝；CTRL+前滚——施放1级魔爆术。
按下CTRL后本宏不会显示魔爆术图标代之以制造魔法玛瑙，以便和顶级魔爆术作区别。

滚轮后滚：
#showtooltip
/stopcasting
/use [mod:shift] 侦测魔法;[mod:alt] 特效治疗药水;[mod:ctrl] 防护火焰结界;防护冰霜结界
说明：滚轮后滚——施放防护冰霜结界；SHIFT+后滚——施放侦测魔法；
ALT+后滚——使用大红；CTRL+后滚——施放防护火焰结界。

鼠标按键4：
#showtooltip
/use [mod:shift] 诺格弗格药剂;[mod:alt] 沙漏;[mod:ctrl] 14;13
说明：鼠标侧键——使用第一个饰品；SHIFT+侧键——使用诺格弗格药剂；
ALT+侧键——使用沙漏；CTRL+侧键——使用第二个饰品。

[右边动作条一]
1：无宏无快捷键，炉石。

2：
#showtooltip
/cast [mod:alt] 传送：暴风城;传送门：暴风城
说明：点击——暴风城门；ALT+点击——单传暴风城。

3:
#showtooltip
/cast [mod:alt] 传送：铁炉堡;传送门：铁炉堡
说明：点击——铁炉堡门；ALT+点击——单传铁炉堡。

4:
#showtooltip
/cast [mod:alt] 传送：达纳苏斯;传送门：达纳苏斯
说明：点击——达纳苏斯门；ALT+点击——单传达纳苏斯。

5：
#showtooltip
/castsequence [mod:alt,button:2] 造水术(等级 6);[mod:alt] reset=40/ctrl 制造魔法红宝石,制造魔法黄水晶,制造魔法翡翠,制造魔法玛瑙;[button:2] 造水术;造食术
说明：左键——造食术；右键——造水术；ALT+左键——依次制造各种法力宝石：ALT+右键——次级造水术。
制造法力宝石序列在40秒后重置，按住CTRL可强制重置。


[右边动作条二]
1：无宏快捷键T，坐骑。

2：
#showtooltip
/cast [mod:alt,button:2] 烹饪;[mod:alt] 急救;[button:2] 裁缝;附魔
说明：左键——附魔；右键——裁缝；ALT+左键——急救；ALT+右键——烹饪。

3：
#showtooltip
/cast [mod:alt][button:2] 冰甲术;魔甲术
说明：左键——魔甲术；右键或者ALT+点击——冰甲术。

4：

其他可用宏：

#showtooltip
/use 魔法晶水
/use 魔法甜面包
/run mana=string.format("%d",UnitPower("player")/UnitPowerMax("player")*100) SendChatMessage(mana.."% 蓝量，需要喝水！","yell",nil,nil)
说明：一键吃喝，并在大喊频道播报蓝量百分比信息。

#showtooltip
/target [noharm][dead] 血色缚法者
/cleartarget [dead][help]
/cancelaura 寒冰屏障
/cast [mod:alt] 缓落术;[mod:ctrl,@mouseover,harm,nodead][mod:ctrl] 变形术;火焰冲击
/cast [nomod] 射击
/run if(GetRaidTargetIndex("target")~=6)then SetRaidTarget("target",6)end
说明：可替代主贴里的火冲宏，附带锁定特定目标功能(例如血色缚法者)并给该目标上标记。

/console cameraDistanceMaxZoomFactor 1
/run SetCVar("alwaysCompareItems","0")
/run UIErrorsFrame:Hide()
说明：镜头距离默认值；取消装备对比，按SHIFT依然可以对比；取消错误提示。

/console cameraDistanceMaxZoomFactor 4
说明：镜头距离最大值。


---------------------------------------------------------------------------
---------------------------------------------------------------------------
战士版传送门：
https://bbs.nga.cn/read.php?tid=20419502
------------------------------------------------------------------------------------------------------------------------------------------------------

在哪在哪呢啊

赶上直播了，楼主威武

mark
坐等大神

马克 坐等直播

不错不错，楼主在如今的法师区简直是一股清流，有心了。
顺带提几点建议:
1、一级暴雪一级奥爆一级冰箭很重要，建议和顶级的用alt捆绑。
2、切换目标很重要，建议单独设置键位
3、17个键位其实是不够用的，特别是学工程主打pvp的法师，铁皮手雷，地精头盔，地精火箭靴，侏儒网，死亡射线，缩小，末日颅骨，各种反射器等等都要快捷释放，具体设置自行摸索，可以买带侧键的鼠标。
4、鼠标中键不建议设置如急冷闪现等关键技能，容易和滚轮上/下滑误触，查看聊天记录的时候设置在滚轮的按键也容易误放，个人建议滚轮按键设置成切换目标。

这才是NGA本来应该有的亚子

收藏晚上学习学习

你确定1级法术能放到宏里？

楼主厉害，基本把该设置的都覆盖了，补充一点个人使用良好的体验：wsad四个键食指、中指操控，配合大拇指alt判定还可以扩展4个出来，我是设置了上马、炉石、大红、打蓝。

妈妈哪

引用 星日月夜空2019-11-01 10:15

不错不错，楼主在如今的法师区简直是一股清流，有心了。
顺带提几点建议:
1、一级暴雪一级奥爆一级冰箭很重要，建议和顶级的用alt捆绑。

1、暴风雪有鼠标选择施法区域的过程，所以不在出手速度要求最高的那一批技能之列。
因此我把一级和顶级暴风雪都放在组合键上，不过是修饰键加Q、E这两组出手依然非常快、非常准的按键。
一级和顶级魔爆术的确用了修饰键绑定在一起。
一级寒冰箭出手速度要求比较高，没有用组合键，而是单独放在4键。
2、切换目标Tab键并没有变动。
3、工程学铁皮手雷的确需要放在一个恰当的键位上。
但是给各种杂七杂八的道具都安排一个快捷键，我认为会降低操作质量。
4、急冷的快捷键实际上在F1上，和寒冰护体在一起，中键上只是顺便也给冰箱放了一个急冷。
实践显示，滚轮放技能并不会误按，而有无与伦比的时效优势。
不过因鼠标肩负点击和转向的重任，所以滚轮上不宜放置目标指向性技能。

很不错啊，键位省很多

mark
太赞了

?收藏马克

昨晚看到楼主发了一段以为太监了 谁知道这么猛

看到ALT+的施法就不想看了

占楼备用，站楼备用